%%
%% This is file `csydiod.mf',
%% generated with the docstrip utility.
%%
%% The original source files were:
%%
%% circ.dtx  (with options: `csydiod')
%% Copyright 1997  Andreas Tille / Sebastian Tannert
%% 
%% This file is part of the CIRC package
%% -------------------------------------
%%   This package is distributed in the hope that it will be useful,
%%   but WITHOUT ANY WARRANTY; without even the implied warranty of
%%   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
%% 
%%   For error reports concerning UNCHANGED versions of this file no
%%   more than one year old, see CIRC.DVI.
%% 
%% IMPORTANT COPYRIGHT NOTICE:
%% 
%% You are NOT ALLOWED to distribute this file alone.
%% 
%% You are allowed to distribute this file under the condition that it
%% is distributed together with all the files listed in circ.txt.
%% 
%% If you receive only some of these files from someone, complain!
%% 
%% You are NOT ALLOWED to change this file.

input csym;
designsize:=1lLE#;

def diode =  % "uberarbeiten
  numeric pl;
  pl:=.5(did_lt-did_wd);
  z0=(0,0);
  z1=z0+(pl,0);
  z2=z1+(did_wd,0);
  z3=z2+(pl,0);
  z4-z5=z6-z7=(0,did_ht);
  z1=.5[z4,z5];
  z2=.5[z6,z7];
  z8=z4+(did_zlt,0);
  z9=z0+(0,thy_ht);

  z10=.35[z5,z7];
  z11=z10-(.5Dcap_spc,0);
  z12=z10+(.5Dcap_spc,0);
  y13=y15; y14=y16;
  x13=x14; x15=x16;
  y13-y14=Dcap_ht;
  z11=.5[z13,z14];
  z12=.5[z15,z16];
  z17=z11-(Dcap_wd,0);
  z18=z12+(Dcap_wd,0);

  pickup pensquare scaled normalline;
  draw z0--z1;
  draw z2--z3;
  draw z4--z5;
  draw  z1--z6--z7--cycle;
enddef;

def Dcap =
  pickup pensquare scaled normalline;
  draw z17--z11;
  draw z13--z14;
  draw z15--z16;
  draw z12--z18;
enddef;

def led_arrows =  % "uberarbeiten
  numeric pl;
  numeric x[],y[];
  transform arr_a,arr_b;
  pickup pencircle scaled thinline;
  pl:=.5(did_lt-did_wd);
  z0=(0,0);
  z4=z0+(pl,0);
  z1=z0+(led_lt,0);
  (z1-z2)=(led_wd,0) rotated led_phi;
  (z1-z3)=(led_wd,0) rotated -led_phi;
  arr_a:=identity rotated led_psi shifted (z4+(led_spx,led_spy));
  arr_b:=identity rotated led_psi shifted (z4+(led_spx,led_spy+led_spc));
  draw (z0--z1) transformed arr_a;
  draw (z0--z1) transformed arr_b;
  draw (z2--z1) transformed arr_a;
  draw (z2--z1) transformed arr_b;
  draw (z3--z1) transformed arr_a;
  draw (z3--z1) transformed arr_b;
enddef;

"Diode";
fourchars(0)(diode)(z3)(.5did_ht#,did_lt#,.5did_ht#);

"Z-Diode";
fourchars(4)(diode; draw z4--z8)(z3)(.5did_ht#,did_lt#,.5did_ht#);

"LED";
fourfourchars(8)(diode; led_arrows)(z3)(1.2did_ht#,did_lt#,.5did_ht#);

"Kapazit"&ditto&"atsdiode";
fourchars(16)(diode; Dcap)(z3)(.5did_ht#,did_lt#,.65did_ht#);

"Thyristor";

end;